[Maypole] Apache2 support for maypole.

[Marcus Ramberg]

This is a multi-part message in MIME format.
--------------050300000507030609080601
Content-Type: text/plain; charset=ISO-8859-1; format=flowed
Content-Transfer-Encoding: 7bit
I've been hacking a little on maypole, and I now have a working Apache2 
driver for Maypole. It requires a small patch to the base maypole class 
as included below, because modperl2 doesn't like the global 
Apache->request method. This shouldn't hurt the other driver classes though.

Maypole::Authentication::UserSessionCookie doesn't work yet here, 
(segfaults) but I'm working on it.

Marcus

Index: lib/Maypole.pm
===================================================================
RCS file: /var/cvs/modules/Apache-MVC/lib/Maypole.pm,v
retrieving revision 1.18
diff -p -0 -r1.18 Maypole.pm
*** lib/Maypole.pm      16 Apr 2004 17:17:13 -0000      1.18
--- lib/Maypole.pm      12 May 2004 17:54:32 -0000
*************** sub handler {
*** 55 ****
!     $r->get_request();
--- 55 ----
!     $r->get_request(@_);


--
This e-mail has been protected by Song Networks' virus-scan service:
http://www.securemail.no

--------------050300000507030609080601
Content-Type: text/plain;
 name="MVC.pm"
Content-Transfer-Encoding: 7bit
Content-Disposition: inline;
 filename="MVC.pm"

package Apache2::MVC;
use base 'Maypole';
use Apache2;
use Apache::RequestRec;
use Apache::RequestUtil;
use Apache::Request;
use APR::URI;
use strict;
use warnings;
our $VERSION = "0.1";

sub get_request {
    my ($self,$r)=@_;
    $self->{ar} = Apache::Request->new($r);
}

sub parse_location {
    my $self = shift;
    $self->{path} = $self->{ar}->uri;
    my $loc = $self->{ar}->location;
    no warnings 'uninitialized';
    $self->{path} =~ s/^($loc)?\///;
    $self->parse_path;

    $self->{params} = { $self->_mod_perl_args($self->{ar})};
    $self->{query} = { $self->_mod_perl_args($self->{ar})};
}

sub send_output {
    my $r = shift;
    $r->{ar}->content_type($r->{content_type});
    $r->{ar}->headers_out->set("Content-Length" => length $r->{output});
    print ($r->{output});
}

sub get_template_root {
    my $r = shift;
    $r->{ar}->document_root . "/". $r->{ar}->location;
}

sub _mod_perl_args
{
    my ($self, $apr) = @_;
    my %args;
    foreach my $key ( $apr->param ) {
        my @values = $apr->param($key);
        $args{$key} = @values == 1 ? $values[0] : \@values;
    }
    return %args;
}

1;

=head1 NAME

Apache2::MVC - Apache2 front-end to Maypole

=head1 SYNOPSIS

    package BeerDB;
    use base 'Apache2::MVC';
    BeerDB->setup("dbi:mysql:beerdb");
    BeerDB->config->{uri_base} = "http://your.site/";
    BeerDB->config->{display_tables} = [qw[beer brewery pub style]];
    # Now set up your database:
    # has-a relationships
    # untaint columns

    1;

=head1 DESCRIPTION

Maypole is a Perl web application framework to Java's struts. It is 
essentially completely abstracted, and so doesn't know anything about
how to talk to the outside world. C<Apache2::MVC> is a mod_perl2 based
subclass of Maypole for.

To use it, you need to create a package which represents your entire
application. In our example above, this is the C<BeerDB> package.

This needs to first inherit from C<Apache2::MVC>, and then call setup.
This will give your package an Apache2-compatible C<handler> subroutine,
and then pass any parameters onto the C<setup_database> method of the
model class. The default model class for Maypole uses L<Class::DBI> to 
map a database to classes, but this can be changed by messing with the
configuration. (B<Before> calling setup.)

Next, you should configure your application through the C<config>
method. Configuration parameters at present are:

=over

=item uri_base

You B<must> specify this; it is the base URI of the application, which
will be used to construct links.

=item display_tables

If you do not want all of the tables in the database to be accessible,
then set this to a list of only the ones you want to display

=item rows_per_page

List output is paged if you set this to a positive number of rows.

=back

You should also set up relationships between your classes, such that,
for instance, calling C<brewery> on a C<BeerDB::Beer> object returns an
object representing its associated brewery.

For a full example, see the included "beer database" application.

=head1 INSTALLATION

Create a driver module like the one above.

Put the following in your Apache config:

    <Location /beer>
        SetHandler perl-script
        PerlHandler BeerDB
    </Location>

Copy the templates found in F<templates/factory> into the
F<beer/factory> directory off the web root. When the designers get
back to you with custom templates, they are to go in
F<beer/custom>. If you need to do override templates on a
database-table-by-table basis, put the new template in
F<beer/I<table>>. 

This will automatically give you C<add>, C<edit>, C<list>, C<view> and
C<delete> commands; for instance, a list of breweries, go to 

    http://your.site/beer/brewery/list

For more information about how the system works and how to extend it,
see L<Maypole>.

=head1 AUTHOR

Simon Cozens, C<simon@cpan.org>
Ported to Apache2 by Marcus Ramberg C<marcus@thefeed.no>

=head1 LICENSE

You may distribute this code under the same terms as Perl itself.

--------------050300000507030609080601--